Add barometer graphgraph

This is based mostly on my work from asteroid-health (https://git.dodorad.io/dodoradio/asteroid-health). Some tweaks have been applied on top of this code, which might prove useful in asteroid-health as well.

1 files changed, 81 insertions, 0 deletions

diff --git a/src/graphs/BarometerGraph.qml b/src/graphs/BarometerGraph.qml
new file mode 100644
index 0000000..42f378d
--- /dev/null
+++ b/src/graphs/BarometerGraph.qml
@@ -0,0 +1,81 @@
+/*
+ * Copyright (C) 2023 Arseniy Movshev <dodoradio@outlook.com>
+ *               2019 Florent Revest <revestflo@gmail.com>
+ *
+ * This program is free software: you can redistribute it and/or modify
+ * it under the terms of the GNU General Public License as published by
+ * the Free Software Foundation, either version 3 of the License, or
+ * (at your option) any later version.
+ *
+ * This program is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+ * GNU General Public License for more details.
+ *
+ * You should have received a copy of the GNU General Public License
+ * along with this program. If not, see <http://www.gnu.org/licenses/>.
+ */
+
+import QtQuick 2.15
+import org.asteroid.controls 1.0
+
+import org.asteroid.health 1.0
+import org.asteroid.sensorlogd 1.0
+
+Item {
+    id: graph
+    property date startTime: new Date()
+    property date endTime: new Date()
+
+    onStartTimeChanged: baroGraph.loadGraphData(baroDataLoader.getDataFromTo(startTime,endTime))
+    onEndTimeChanged: baroGraph.loadGraphData(baroDataLoader.getDataFromTo(startTime,endTime))
+
+    Component.onCompleted: {
+        baroGraph.loadGraphData(baroDataLoader.getDataFromTo(startTime,endTime))
+    }
+    BarometerDataLoader { id: baroDataLoader
+        onDataChanged: baroGraph.loadGraphData(getDataFromTo(startTime,endTime))
+    }
+    VerticalLabels { // labels column
+        id: markerParent
+        width: parent.width/8
+        startValue: baroGraph.minValue
+        endValue: baroGraph.maxValue
+        maxLabels: 5
+        minLabels: 2
+        scaleFactor: 0.01
+        labelK: false
+        anchors {
+            left: parent.left
+            top: baroGraph.top
+            bottom: baroGraph.bottom
+            topMargin: baroGraph.lineWidth/2
+            bottomMargin: anchors.topMargin
+        }
+    }
+    LineGraph {
+        id: baroGraph
+        anchors {
+            left: markerParent.right
+            right: parent.right
+            top: parent.top
+            bottom: labelsRow.top
+        }
+        relativeMode: true
+        lineWidth: 4
+    }
+    TimeLabels {
+        id: labelsRow
+        height: Dims.w(5)
+        startTime: baroGraph.minTime / 1000
+        endTime: baroGraph.maxTime / 1000
+        maxLabels: 6 //try to get the graph to look a little bit better
+        anchors {
+            bottom: parent.bottom
+            left: baroGraph.left
+            right: baroGraph.right
+            rightMargin: baroGraph.lineWidth/2
+            leftMargin: anchors.rightMargin
+        }
+    }
+}